MiniRobotLanguage (MRL)
Show Bubble Text
Show Help Text "in a Bubble"
Intention
This command is used to display textual Information that can reference a control, or a point on Screen.
You can influence where the Bubble is displayed as well as the Text-Size.
You can also have that small "comic-arrow" or not. Let's see some examples.
' First we locate a Button
STW.ct|PBWindowClass:0|Dialog #1
SCW.nict|1|1009|Button|OK
' Next we how the Bubble-Text
SBT.Click here to continue.
' We need to rest, as the text runs in the Background
PAU.8
ENR.
Why do we need the "PAU.8" ?
It's needed because the Command - per default runs in the Background.
It starts to display the Bubble-Text, and WHILE the text is displayed the Script continues to run.
Now, if the Script ends - the Bubble will also be closed!
To prevent this you can add a second Parameter:
STW.ct|PBWindowClass:0|Dialog #1
SCW.nict|1|1009|Button|OK
SBT.Click here to continue.|#
ENR.
In this case you can leave away the "PAU.8" because the Bubble will stay for 6 Seconds (this is the default time, if no other time is specified).
Now what you see is that the Bubble is always "on Top". That's a default setting.
If you do not want that use that other Parameter "@":
STW.ct|PBWindowClass:0|Dialog #1
SCW.nict|1|1009|Button|OK
SBT.Click here to continue.|#@
ENR.
Here is another example that uses a custom FontName:
$$XPO=-100
$$YPO=100
$$PAR=FS:14 t:10 cs:1 ax:$$XPO ay:$$YPO vc:1 FN:"Tomorrow People" #
Following is a more complex Sample.
' More complex Sample
STW.ct|IEFrame| - Internet Explorer
$$TXT=These will make the script run with full speed. $crlf$
$$TXT=$$TXT $$TXT$$TXT$$TXT$$TXT$$TXT$$TXT
FOR.$$CNT|1|5
CAL.$$XPO=(-120*$$CNT)
CAL.$$YPO=100*$$CNT
$$PAR=FS:14 t:10 cs:1 ax:$$XPO ay:$$YPO vc:1
SBT.$$TXT|$$PAR
NEX.
PAU.40
ENR.
Which will produce this picture:
Syntax
SBT.P1[|P2][#@]
Parameter Explanation
P1 - Text to be displayed
This can be a Text or a Text-Variable that will be displayed in the Bubble-Text.
It may contain $crlf$ - these will be treated as NewLine".
P2 - (optional) Flags and Parameters
@ - will prevent the "TOPMOST-Flag".
# - will have the Script wait until the Bubble-time is over.
T:(NUM) - Time in Seconds, specify how long the Bubble-Text shall be displayed. The Bubble will anyway be closed when the Script ends! If not given the default time is 6 Seconds.
FS:(NUM) - FontSize: An number that specifies the size of the Font that shall be used.
FN:"FONTNAME" - Specify any Font that is on your Computer. Notice that the Fontname must be between " ".
VC:(NUM) - Vertical Center. The given number can be 0,1 or 2. Each number will have a different effect. 0 is the default.
HC:(NUM) - Horizontal Center. The given number can be 0,1 or 2. Each number will have a different effect. 0 is the default.
AX:(NUM) - Adjusting X-Position. This value can be negative or positive. It will move the Bubble by this number of pixels left (if negative value) or right.
AY:(NUM)- Adjusting Y-Position. This value can be negative or positive. It will move the Bubble by this number of pixels up (if negative value) or down.
MP: - Mouse Position. If specified then the Bubble will be generated at the Position where the Mouse Pointer is.
LA: - Left Align. If not specified the Text is always Centered in the Bubble.
CS: - Center on Screen. This will Center the Bubble on Screen. Use this if you have no Window or Button.
NC: - NoCorner. Will remove the "Comic-Arrow".
WB:(NUM) - WordBreak. Switches Wordbreak on. NUM is a numerical value, for example 32.
Using 32 will make the Text to appear in a Single line without Newlines. Other values may have other effects depending on the situation.
Example
'***********************************************
' SBT. - Sample
'***********************************************
STW.ct|PBWindowClass:0|Dialog #1
SCW.nict|1|1009|Button|OK
SBT.Click here to continue.|#@
ENR.
'***********************************************
$$PAR=FS:12 t:10 cs:1 ax:$$XPO ay:$$YPO vc:1 @ wb:64
$$TXT=Hallo All!
SBT.$$TXT|$$PAR
'***********************************************
' More complex Sample
STW.ct|IEFrame| - Internet Explorer
$$TXT=These will make the script run with full speed. $crlf$
$$TXT=$$TXT $$TXT$$TXT$$TXT$$TXT$$TXT$$TXT
FOR.$$CNT|1|5
CAL.$$XPO=(-120*$$CNT)
CAL.$$YPO=100*$$CNT
$$PAR=FS:14 t:10 cs:1 ax:$$XPO ay:$$YPO vc:1 FN:"Tomorrow People" @
SBT.$$TXT|$$PAR
NEX.
PAU.40
ENR.
Remarks
-
Limitations:
-
See also:
• DMP. - Dump internat Informations